;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

;

; Author : ADI - Apps www.analog.com/MicroConverter

;

; Date : 28 Sept 1999

;

; File : PSMon.asm

;

; Hardware : ADuC824

;

; Description : Demonstrates use of on-chip power supply monitor.

; In normal operation, this code flashes the LED at

; approximately 5Hz. When Vdd drops below the user

; specified trip-point (here 4.63V) the PSM interrupt

; is executed. once inside this interrupt service

; routine, this code waits until the PSM interrupt

; bit becomes zero again, indicating that the power

; supply is again above the trip point and has been

; there for at least 256ms. at this point, a RETI

; instruction is executed, and normal code execution

; is resumed, indicated by the flashing LED.

;

;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

$MOD824 ; Use 8052&ADuC824 predefined symbols

LED EQU P3.4 ; P3.4 drives red LED on eval board

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

; BEGINNING OF CODE

CSEG

ORG 0000h

JMP MAIN ; jump to main program

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

; INTERRUPT VECTOR SPACE

ORG 0043h ; (PSM ISR)

CLR LED ; turn off the LED to indicate fault

; most often, a routine would here be called to store critical values

; in user Flash/EE space and wait in a "safe" state of code execution

; until the PSM interrupt bit becomes zero indicating that adequate

; power supply voltage has returned.

CHECK: MOV A,PSMCON ; PSMCON.5 is the PSM interrupt bit..

JB ACC.5,CHECK ; ..it is cleared only when Vdd has

; remained above the trip point for

; 256ms or more.

SETB LED

RETI ; return only when "all's well"

;====================================================================

; MAIN PROGRAM

ORG 0060h ; start program above interrupts

MAIN:

MOV PSMCON, #0C1H ; enable PSM with

; AVdd 4.63V threshold

; DVdd 4.63V threshold

MOV IEIP2, #22H ; enable PSM interrupt

; high priority for PSM interrupt

SETB EA ; enable interrupts

FLASH: ; Main Routine would go here

CPL LED ; blink LED indicating norm operation

CALL DELAY ; delay 100ms

JMP FLASH ; loop

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

; SUBROUTINE

DELAY: ; delay 100ms

MOV R2,#50 ; 50 \* 2000us = 100ms

DLY1: MOV R3,#132 ; 132 \* 15.62us = 2000us

DJNZ R3,$ ; sit here for 2000us

DJNZ R2,DLY1 ; repeat 50 times (100ms total)

RET

;\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_\_

END